[TheMexican]

1)Well here's what I figured out so far; got the panel to drop down when I rollover at a Ymouse of 70. However, I want to put an input form in the panel; but if the users mouse goes below a Ymouse of 70 the panel slides back-up.

So you say '"Well just make the Ymouse more than 70 or whatever the length of the form field"'

Here's the problem: I plan on putting a FullScreen button on my Main Stage (about 1/4 distance from the top).
When the user moves their mouse anywhere near that FS button, it's going to bring down the panel. I don't want that.

What I want is for the panel to slide back-up when the users mouse is at the bottom of the panel. Much like the claudiesong.com site.

2)I did a google search on how to create a down/disable button state. There were so many out there but none that I could understand without an actual working fla file. What I wanted to do is when the viewer first rolls over the panel; the "Helen Newman" title is already highlighted with content.
I created a movie clip button with an instance name of 'btn1', and another movie clip inside of that one with an instance name 'btnStates_mc' and inside of that is my timeline animation(which doesn't work when I place my button on the main stage). Could you please take a look at my fla file.


Am I making any sense?

Thanks for any help you can throw my way.

[thatwebsitegirl]

You need to break up you functionality. You will need one button at the top of the screen which is not attached to the panel that invokes that "slide open" rollover behavior. Then, the easiest way to close it would be to create a seperate button at the bottom of your panel that invokes the "slide closed" rollover behavior.

I would also enable or disable the buttons that you don't need. Here's the code:

//first i would define by opened and closed y values and a move increment... 
// i'm just making stuff up here
openY = panel._y+panel._height;
closedY = panel._y;
deltaY = panel._height/10;
// then i would set up the behaviors of the buttons
showPanelButton._visible = true;
showPanelButton.onRollOver = _root.openPanel;
panel.hidePanelButton._visible = false;
panel.hidePanelButton.onRollOver = _root.closePanel;
 
function openPanel() { 
    // create a looping function to drop the panel down
    panel.onEnterFrame = function() {
        if ((this._y+_root.deltaY) < _root.openY) {
            this._y += _root.deltaY;
        } else {
            // kill the looping behavior
            this.onEnterFrame = null;
            // assign the final resting place of the panel
            this._y = _root.openY;
            // enable/disable the buttons
            this._parent.showPanelButton._visible = false;
            this.hidePanelButton._visible = true;
        }
    }
};
function closePanel() { 
    // start a loop to slide the panel up
    panel.onEnterFrame = function() {
        if ((this._y - _root.deltaY) > _root.closedY) {
            this._y -= _root.deltaY;
        } else {
            // kill the looping behavior
            this.onEnterFrame = null;
            // assign the final resting place of the panel
            this._y = _root.closedY;
            // enable/disable the buttons
            this._parent.showPanelButton._visible = true;
            this.hidePanelButton._visible = false;
        }
    }
}; 

slidingPanel.zip