[tim8w]

Does anyone have sample code on how to set the StartPosition for the CommonDialogs? In particular, I'm looking to create another class that inherits from ColorDialog and add the StartPosition functionality. I have seen a rather complicated way done in C# for the OpenFileDialog. Has no one done this for VB.Net yet?

[digioz]

Not sure if this is exactly what you are looking for, but here is something to play around with. This is the VB.NET version of the following C# article found here:

http://www.codeproject.com/KB/cs/getsavefilename.aspx

In particular, take a look at the "SetWindowPos()" call in "HookProc".

Custom Dialog Form:

' 20070325: George Birbilis ([EMAIL="birbilis@kagi.com"]birbilis@kagi.com[/EMAIL])
Imports System.Text
Imports System.Text.Encoding
Imports System.Drawing
Imports System.Collections
Imports System.ComponentModel
Imports System.Windows.Forms
Imports System.Data
Imports System.Runtime.InteropServices
 
Public Class SaveFileDialogWithEncoding
    Inherits Component
#Region "Enums"
    'note the order of these is important
    Public Enum EncodingTypes
        ANSI = 0
        UTF8
        UTF16
        UTF7
        UTF32
        UNKNOWN
    End Enum
#End Region
 
#Region "Fields"
    Protected Encodings As System.Text.Encoding() = New System.Text.Encoding() {ASCII, UTF8, Unicode, UTF7, UTF32}
    Private m_LabelHandle As Integer = 0
    Private m_ComboHandle As Integer = 0
    Private m_Filter As String = ""
    Private m_DefaultExt As String = ""
    Private m_FileName As String = ""
    Private m_EncodingType As EncodingTypes
    Private m_ActiveScreen As Screen
#End Region
 
#Region "Constants"
    Private Const OFN_ENABLEHOOK As Integer = 32
    Private Const OFN_EXPLORER As Integer = 524288
    Private Const OFN_FILEMUSTEXIST As Integer = 4096
    Private Const OFN_HIDEREADONLY As Integer = 4
    Private Const OFN_CREATEPROMPT As Integer = 8192
    Private Const OFN_NOTESTFILECREATE As Integer = 65536
    Private Const OFN_OVERWRITEPROMPT As Integer = 2
    Private Const OFN_PATHMUSTEXIST As Integer = 2048
    Private Const SWP_NOSIZE As Integer = 1
    Private Const SWP_NOMOVE As Integer = 2
    Private Const SWP_NOZORDER As Integer = 4
    Private Const WM_INITDIALOG As Integer = 272
    Private Const WM_DESTROY As Integer = 2
    Private Const WM_SETFONT As Integer = 48
    Private Const WM_GETFONT As Integer = 49
    Private Const CBS_DROPDOWNLIST As Integer = 3
    Private Const CBS_HASSTRINGS As Integer = 512
    Private Const CB_ADDSTRING As Integer = 323
    Private Const CB_SETCURSEL As Integer = 334
    Private Const CB_GETCURSEL As Integer = 327
    Private Const WS_VISIBLE As UInteger = 268435456
    Private Const WS_CHILD As UInteger = 1073741824
    Private Const WS_TABSTOP As UInteger = 65536
    Private Const CDN_FILEOK As Integer = -606
    Private Const WM_NOTIFY As Integer = 78
#End Region
 
#Region "Properties"
    Public Property DefaultExt() As String
        Get
            Return m_DefaultExt
        End Get
        Set(ByVal value As String)
            m_DefaultExt = value
        End Set
    End Property
    Public Property Filter() As String
        Get
            Return m_Filter
        End Get
        Set(ByVal value As String)
            m_Filter = value
        End Set
    End Property
    Public Property FileName() As String
        Get
            Return m_FileName
        End Get
        Set(ByVal value As String)
            m_FileName = value
        End Set
    End Property
    Public Property EncodingType() As EncodingTypes
        Get
            Return m_EncodingType
        End Get
        Set(ByVal value As EncodingTypes)
            m_EncodingType = value
        End Set
    End Property
    Public Property Encoding() As Encoding
        Get
            Return Encodings(m_EncodingType)
        End Get
        Set(ByVal value As Encoding)
            Dim i As Integer = 0
            For Each enc As Encoding In Encodings
                If enc.Equals(value) Then
                    m_EncodingType = CType(i, EncodingTypes)
                    Exit Property
                End If
            Next enc
            m_EncodingType = EncodingTypes.UNKNOWN
        End Set
    End Property
#End Region
 
#Region "Methods"
    <DllImport("Comdlg32.dll", CharSet:=CharSet.Auto, SetLastError:=True)> _
    Private Shared Function GetSaveFileName(ByRef lpofn As OPENFILENAME) As Boolean
    End Function
    <DllImport("Comdlg32.dll")> _
    Private Shared Function CommDlgExtendedError() As Integer
    End Function
    <DllImport("user32.dll")> _
    Private Shared Function SetWindowPos(ByVal hWnd As Integer, ByVal hWndInsertAfter As Integer, ByVal X As Integer, ByVal Y As Integer, ByVal cx As Integer, ByVal cy As Integer, ByVal uFlags As UInteger) As Boolean
    End Function
    <DllImport("user32.dll")> _
    Private Shared Function GetWindowRect(ByVal hWnd As Integer, ByRef lpRect As RECT) As Boolean
    End Function
    <DllImport("user32.dll")> _
    Private Shared Function GetParent(ByVal hWnd As Integer) As Integer
    End Function
    <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
    Private Shared Function SetWindowText(ByVal hWnd As Integer, ByVal lpString As String) As Boolean
    End Function
    <DllImport("user32.dll")> _
    Private Overloads Shared Function SendMessage(ByVal hWnd As Integer, ByVal Msg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As Integer
    End Function
    <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
    Private Overloads Shared Function SendMessage(ByVal hWnd As Integer, ByVal Msg As Integer, ByVal wParam As Integer, ByVal lParam As String) As Integer
    End Function
    <DllImport("user32.dll")> _
    Private Shared Function DestroyWindow(ByVal hwnd As Integer) As Boolean
    End Function
    <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
    Private Shared Function GetDlgItem(ByVal hDlg As Integer, ByVal nIDDlgItem As Integer) As Integer
    End Function
    <DllImport("user32.dll", CharSet:=CharSet.Auto)> _
    Private Shared Function CreateWindowEx(ByVal dwExStyle As Integer, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As UInteger, ByVal x As Integer, ByVal y As Integer, ByVal nWidth As Integer, ByVal nHeight As Integer, ByVal hWndParent As Integer, ByVal hMenu As Integer, ByVal hInstance As Integer, ByVal lpParam As Integer) As Integer
    End Function
    <DllImport("user32.dll")> _
    Private Shared Function ScreenToClient(ByVal hWnd As Integer, ByRef lpPoint As POINT) As Boolean
    End Function
 
    Private Function HookProc(ByVal hdlg As Integer, ByVal msg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As Integer
        Select Case (msg)
            Case WM_INITDIALOG
                'we need to centre the dialog
                Dim sr As Rectangle = m_ActiveScreen.Bounds
                Dim cr As RECT = New RECT
                Dim parent As Integer = GetParent(hdlg)
                GetWindowRect(parent, cr)
                Dim x As Integer = CInt((sr.Right + (sr.Left - (cr.Right - cr.Left))) / 2)
                Dim y As Integer = CInt((sr.Bottom + (sr.Top - (cr.Bottom - cr.Top))) / 2)
                SetWindowPos(parent, 0, x, y, (cr.Right - cr.Left), ((cr.Bottom - cr.Top) + 32), SWP_NOZORDER)
                'we need to find the label to position our new label under
                Dim fileTypeWindow As Integer = GetDlgItem(parent, 1089)
                Dim aboveRect As RECT = New RECT
                GetWindowRect(fileTypeWindow, aboveRect)
                'now convert the label's screen co-ordinates to client co-ordinates
                Dim point As POINT = New POINT
                point.X = aboveRect.Left
                point.Y = aboveRect.Bottom
                ScreenToClient(parent, point)
                'create the label
                Dim labelHandle As Integer = CreateWindowEx(0, "STATIC", "mylabel", (WS_VISIBLE _
                                        Or (WS_CHILD Or WS_TABSTOP)), point.X, (point.Y + 12), 200, 100, parent, 0, 0, 0)
                SetWindowText(labelHandle, "&Encoding:") 'should show with same encoding as system dialog or not show label at all
                Dim fontHandle As Integer = SendMessage(fileTypeWindow, WM_GETFONT, 0, 0)
                SendMessage(labelHandle, WM_SETFONT, fontHandle, 0)
                'we now need to find the combo-box to position the new combo-box under
                Dim fileComboWindow As Integer = GetDlgItem(parent, 1136)
                aboveRect = New RECT
                GetWindowRect(fileComboWindow, aboveRect)
                point = New POINT
                point.X = aboveRect.Left
                point.Y = aboveRect.Bottom
                ScreenToClient(parent, point)
                Dim rightPoint As POINT = New POINT
                rightPoint.X = aboveRect.Right
                rightPoint.Y = aboveRect.Top
                ScreenToClient(parent, rightPoint)
                'we create the new combobox
                Dim comboHandle As Integer = CreateWindowEx(0, "ComboBox", "mycombobox", (WS_VISIBLE _
                                        Or (WS_CHILD _
                                        Or (CBS_HASSTRINGS _
                                        Or (CBS_DROPDOWNLIST Or WS_TABSTOP)))), point.X, (point.Y + 8), (rightPoint.X - point.X), 100, parent, 0, 0, 0)
                SendMessage(comboHandle, WM_SETFONT, fontHandle, 0)
                'and add the encodings we want to offer
                SendMessage(comboHandle, CB_ADDSTRING, 0, "ANSI")
                SendMessage(comboHandle, CB_ADDSTRING, 0, "Unicode (UTF-8)")
                SendMessage(comboHandle, CB_ADDSTRING, 0, "Unicode (UTF-16)")
                SendMessage(comboHandle, CB_ADDSTRING, 0, "Unicode (UTF-7)")
                SendMessage(comboHandle, CB_ADDSTRING, 0, "Unicode (UTF-32)")
                SendMessage(comboHandle, CB_SETCURSEL, CType(m_EncodingType, Integer), 0)
                'remember the handles of the controls we have created so we can destroy them after
                m_LabelHandle = labelHandle
                m_ComboHandle = comboHandle
            Case WM_DESTROY
                'destroy the handles we have created
                If (m_ComboHandle <> 0) Then
                    DestroyWindow(m_ComboHandle)
                End If
                If (m_LabelHandle <> 0) Then
                    DestroyWindow(m_LabelHandle)
                End If
            Case WM_NOTIFY
                'we need to intercept the CDN_FILEOK message
                'which is sent when the user selects a filename
                Dim nmhdr As NMHDR = CType(Marshal.PtrToStructure(New IntPtr(lParam), GetType(NMHDR)), NMHDR)
                If (nmhdr.Code = CDN_FILEOK) Then
                    'a file has been selected
                    'we need to get the encoding
                    m_EncodingType = CType(SendMessage(m_ComboHandle, CB_GETCURSEL, 0, 0), EncodingTypes)
                End If
        End Select
        Return 0
    End Function
 
    Public Function ShowDialog() As DialogResult
        'set up the struct and populate it
        Dim ofn As OPENFILENAME = New OPENFILENAME
        ofn.lStructSize = Marshal.SizeOf(ofn)
        ofn.lpstrFilter = (m_Filter.Replace("|", Microsoft.VisualBasic.Chr(0)) + Microsoft.VisualBasic.Chr(0))
        ofn.lpstrFile = (m_FileName + New String(Microsoft.VisualBasic.Chr(32), 512))
        ofn.nMaxFile = ofn.lpstrFile.Length
        ofn.lpstrFileTitle = (System.IO.Path.GetFileName(m_FileName) + New String(Microsoft.VisualBasic.Chr(32), 512))
        ofn.nMaxFileTitle = ofn.lpstrFileTitle.Length
        ofn.lpstrTitle = "Save file as"
        ofn.lpstrDefExt = m_DefaultExt
        'position the dialog above the active window
        ofn.hwndOwner = Form.ActiveForm.Handle
        'we need to find out the active screen so the dialog box is
        'centred on the correct display
        m_ActiveScreen = Screen.FromControl(Form.ActiveForm)
        'set up some sensible flags
        ofn.Flags = (OFN_EXPLORER _
                          Or (OFN_PATHMUSTEXIST _
                          Or (OFN_NOTESTFILECREATE _
                          Or (OFN_ENABLEHOOK _
                          Or (OFN_HIDEREADONLY Or OFN_OVERWRITEPROMPT)))))
        'this is where the hook is set. Note that we can use a C# delegate in place of a C function pointer
        ofn.lpfnHook = New OFNHookProcDelegate(AddressOf HookProc)
        'if we're running on Windows 98/ME then the struct is smaller
        If (System.Environment.OSVersion.Platform <> PlatformID.Win32NT) Then
            ofn.lStructSize = (ofn.lStructSize - 12)
        End If
        'show the dialog
        If Not GetSaveFileName(ofn) Then
            Dim ret As Integer = CommDlgExtendedError()
            If (ret <> 0) Then
                Throw New ApplicationException(("Couldn't show file open dialog - " + ret.ToString))
            End If
            Return DialogResult.Cancel
        End If
        'Birb-start
        Dim oldFilename As String = m_FileName
        m_FileName = ofn.lpstrFile
        Dim cancelCheck As New CancelEventArgs()
        RaiseEvent FileOK(Me, cancelCheck)
        If cancelCheck.Cancel Then
            m_FileName = oldFilename 'restore filename since dialog was canceled
            Return DialogResult.Cancel
        Else
            Return DialogResult.OK
        End If
        'Birb-end
    End Function
    Public Delegate Function OFNHookProcDelegate(ByVal hdlg As Integer, ByVal msg As Integer, ByVal wParam As Integer, ByVal lParam As Integer) As Integer
#End Region
 
#Region "Structures"
    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)> _
    Private Structure OPENFILENAME
        Public lStructSize As Integer
        Public hwndOwner As IntPtr
        Public hInstance As Integer
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrFilter As String
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrCustomFilter As String
        Public nMaxCustFilter As Integer
        Public nFilterIndex As Integer
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrFile As String
        Public nMaxFile As Integer
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrFileTitle As String
        Public nMaxFileTitle As Integer
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrInitialDir As String
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrTitle As String
        Public Flags As Integer
        Public nFileOffset As Short
        Public nFileExtension As Short
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpstrDefExt As String
        Public lCustData As Integer
        Public lpfnHook As OFNHookProcDelegate
        <MarshalAs(UnmanagedType.LPTStr)> _
     Public lpTemplateName As String
        'only if on nt 5.0 or higher
        Public pvReserved As Integer
        Public dwReserved As Integer
        Public FlagsEx As Integer
    End Structure
    Private Structure RECT
        Public Left As Integer
        Public Top As Integer
        Public Right As Integer
        Public Bottom As Integer
    End Structure
    Private Structure POINT
        Public X As Integer
        Public Y As Integer
    End Structure
    Private Structure NMHDR
        Public HwndFrom As Integer
        Public IdFrom As Integer
        Public Code As Integer
    End Structure
#End Region
#Region "Events"
    Public Event FileOK(ByVal sender As System.Object, ByVal e As System.ComponentModel.CancelEventArgs) 'Birb
#End Region
End Class 

Sample Usage:

Dim ofd As SaveFileDialogWithEncoding = New SaveFileDialogWithEncoding
        ofd.DefaultExt = "sql"
        ofd.EncodingType = SaveFileDialogWithEncoding.EncodingTypes.UTF8
        ofd.Filter = "SQL files (*.sql)|*.sql|All files (*.*)|*.*"
        If (ofd.ShowDialog = DialogResult.OK) Then
            MessageBox.Show(String.Format("Name={0}, Encoding={1}", ofd.FileName, ofd.EncodingType))
        End If 

This won't run in .NET 2.0 due to the change in the way .NET 2.0 handles threading. You will have to rewrite it to use a delegate to work in .NET 2.0.

Another very good example of using hooks can be found in this article:

http://msdn.microsoft.com/en-us/magazine/cc188920.aspx

Let me know if this helps. I am very curious to see what you will make of this.


Pete

[tim8w]

Pete,
That's the example I used for GetOpenFileName, GetSaveFileName and ChooseColor dialogs. ChooseFont is much more complicated and I haven't been able to get it to work yet based on this example...

Thanks for the effort!

[digioz]

lol ... ok. I will let you know if I come across anything else on ChooseFont.

By the way, whenever I go to directly reference the "comdlg32.dll" in "system32 folder, I get the following error (VS 2005):

comdlg32_dll_error.jpg

Have you ever come across this error? If so how did you fix it?


Pete

[loumarco]

Thank you for this example. I'm learning quite a bit!

I'm trying to run this example under Vista/VS2008/.NET 2.0. I can change the title of the dialog but the label nor the dropdown appears.

Any one here have issues with this example running under Vista?

[digioz]

Originally Posted by loumarco

Thank you for this example. I'm learning quite a bit!

I'm trying to run this example under Vista/VS2008/.NET 2.0. I can change the title of the dialog but the label nor the dropdown appears.

Any one here have issues with this example running under Vista?

Sorry, I actually had trouble with running it on Vista myself. Tim would be the guy to ask about this, since he got it working correctly. Send him a PM and ask what his solution was.

Pete

[tim8w]

digioz, loumarco;
The code I finally ended up with is for VS2005 and has only been tested on XP. If you want to e-mail me I can send the code to you and you can test it with VS2008 and Vista...

[digioz]

Originally Posted by tim8w

digioz, loumarco;
The code I finally ended up with is for VS2005 and has only been tested on XP. If you want to e-mail me I can send the code to you and you can test it with VS2008 and Vista...

Ah, ok. So you didn't get it to run on Vista either.

Thanks,
Pete

[tim8w]

Not exactly didn't get it to run on Vista, never even tried it in VS2008 or Vista...

[digioz]

Tim,

You will be happy to know that your source code converted from VS 2005 to VS 2008 without any error, and runs fine on Vista. Its only when you try to code it on Vista from scratch that you get the error described for some reason.

Pete